imported>Atariki recovery: Reconstructed from archived HTML; see provenance manifest

2026-10-01T08:51:48Z

Reconstructed from archived HTML; see provenance manifest

Nowa strona

[[File:Vbxe lcd asus t1eh broken.png]]

[[File:Vbxe lcd asus t1eh fixed.png]]

[[File:Svideo lcd asus t1eh broken.png]]

[[File:Svideo lcd asus t1eh fixed.png]]

[[File:Svideo crt commodore 1084s-p1 broken.png]]

[[File:Svideo crt commodore 1084s-p1 fixed.png]]

ANTIC potrafi [[Ramka|wyrysować na ekranie]] 240 linii skanningowych począwszy od 8 linii ekranowej do 247 włącznie. Robi to na podstawie [[ANTIC Display List|Display Listy]].

O ile dla [[Tryby niskiej rozdzielczości|trybów niskiej rozdzielczości]] można wykorzystać pełne 240 linii, o tyle [[Tryby wysokiej rozdzielczości|tryby hires]] ([[Graphics 0|ANTIC 2]], [[ANTIC 3]] i [[Graphics 8|ANTIC F]]), ale również [[Tryby GTIA|tryby GTIA]] ([[Graphics 9]], [[Graphics 10]] i [[Graphics 11]]) bazowane właśnie na trybie [[Graphics 15|ANTIC F]] w takim przypadku powodują zerwanie synchronizacji pionowej, przez co prawidłowa lista wyświetlania może składać się z 239 linii i skoku JVB skutkującego wyświetlaniem jednej pustej linii na samym dole ekranu.

<pre>
dlist:
.byte $0F | $40 ;LMS
.word screen.?part1
:99 .byte $0F

.byte $0F | $40 ;LMS
.word screen.?part2
:99 .byte $0F

.byte $0F | $40 ;LMS
.word screen.?part3
:38 .byte $0F

.byte $41 ;JVB
.word dlist
</pre>

Sposób na poradzenie sobie z problemem opisał [[Rybags]] w wątku [https://forums.atariage.com/topic/165509-overcoming-the-scanline-240-bug Overcoming the Scanline 240 lines "bug"]: sztuczka polega na wyłączeniu [[DMA|DMA dla ekranu]] przed końcem linii 247 - ostatniej kreślonej przez ANTIC, po czym przywróceniu go na początku linii 8 - pierwszej rysowanej przez ANTIC.

<pre>
init:
...
lda #%00100000
ldx #<dlist
ldy #>dlist
sta DMACTLS ;$22F
stx DLPTRS ;$230
sty DLPTRS+1

ldy #<vbint
ldx #>vbint
lda #VBLKD ;7
jsr JSETVBV ;$E45C

ldy #<dlint
ldx #>dlint
lda #%11000000
sty VDSLST ;$200
stx VDSLST+1
sta NMIEN ;$D40E
...

vbint:
lda #8/2
?w cmp VCOUNT ;$D40B
bne ?w

lda #%00100010
sta DMACTL ;$D400
jmp JEXITVB ;$E462

dlint:
pha
lda #%00100000
sta WSYNC ;$D40A
sta DMACTL ;$D400
pla
rti

dlist:
.byte $02 | $40 ;LMS
.word screen
:28 .byte $02
.byte $02 | $80 ;DLI
; .byte $41 ;JVB
; .word dlist
</pre>

W powyższym przykładzie:

* do uzyskania 240 lini hires wykorzystano 30 wierszy trybu [[Graphics 0|ANTIC 2]] (30*8=240), ale równie dobrze można użyć też 240 linii [[Graphics 0|ANTIC F]], jak i 24 wierszy [[ANTIC 3]] (24*10=240),
* do wyłączenia DMA ekranu używane jest przerwanie DLI w ostatnim wierszu ekranu (zajmującego linie 240-247, a zgłaszającego DLI w linii 247),
* a do przywrócenia DMA ekranu przerwanie [[VBL]] (a konkretnie opóźniona faza procedury obsługi przerwania [[SYSVBL|VBLK]]).

Warto zwrócić uwagę na to, że w DMACTLS (czyli cieniu [[Rejestry ANTIC-a#DMACTL|DMACTL]]) DMA dla ekranu jest wyłączone (bity 0 i 1 równe %00) a to z tego powodu, że przed wykonaniem opóźnionej fazy VBLK rejestry ANTIC-a (między innymi DMACTL i DLPTR) są ustawiane na podstawie rejestrów-cieni, zaś włączenie DMA ekranu przed linią 8 spowoduje zerwanie synchronizacji (VBLK zgłaszane jest przez ANTIC w 248 linii skanningowej).

Ostatni skok JVB w Display List jest zbędny ponieważ w międzyczasie na przerwaniu [[SYSVBL|VBLK]] zostaje ustawiona nowa wartość [[Rejestry ANTIC-a#DLPTR|DLPTR]] i ANTIC tego rozkazu już nie czyta.

== Linki ==

* [[ANTIC Display List|Display List]]
* [[Ramka]]
* [[NTSC vs PAL]]
* [[DMA]]
* [[VBL|Przerwanie VBLK]]
* [[Tryby wysokiej rozdzielczości]]
* [[Tryby niskiej rozdzielczości]]
* [[Tryby GTIA]]
* [[Generator znaków]]

[[Kategoria:Niezbędnik kodera]]

Programowanie: Pełny 240-liniowy hires - Historia wersji

imported>Atariki recovery: Reconstructed from archived HTML; see provenance manifest