imported>Atariki recovery: Reconstructed from archived HTML; see provenance manifest

2026-10-01T08:51:48Z

Reconstructed from archived HTML; see provenance manifest

Nowa strona

== Zero ==

<pre>
lda data
ora data+1
...
ora data+N
</pre>

Znacznik Z=1 oznacza, że liczba jest równa 0.
Ta metoda działa również w przypadku liczb BCD (nie wymaga wcześniejszego ustawienia bitu D).

== MAX ==

<pre>
lda data
and data+1
...
and data+N
eor #$FF
</pre>

Znacznik Z=1 oznacza, że liczba jest równa $FF..FF.

Zmieniając

<pre>
eor #$FF
</pre>

na

<pre>
eor #$99
</pre>

można również testować czy liczba BCD jest równa 99..99 (nie wymaga wcześniejszego ustawienia bitu D).

Metoda nie modyfikuje znacznika C.

== Zgodność znaków liczb U2 ==

Test polega na sprawdzeniu MSB argumentów:

<pre>
lda dataA+N
eor dataB+N
</pre>

* N=0 - znaki zgodne
* N=1 - znaki różne

== A=B ==

<pre>
lda dataA
cmp dataB
bne rozne
lda dataA+1
cmp dataB+1
bne rozne
...
lda dataA+N
cmp dataB+N
bne rozne
rowne:
...
rozne:
...
</pre>

lub

<pre>
lda dataA
eor dataB
bne rozne
lda dataA+1
eor dataB+1
bne rozne
...
lda dataA+N
eor dataB+N
bne rozne
rowne:
...
rozne:
...
</pre>

Działa też dla liczb U2 i BCD (nie wymaga wcześniejszego ustawienia bitu D). Ostatnia wersja nie modyfikuje znacznika C.

Wykorzystując zmienną roboczą:

<pre>
lda dataA
eor dataB
sta temp
lda dataA+1
eor dataB+1
ora temp
sta temp
...
lda dataA+N
eor dataB+N
ora temp
</pre>

Znacznik Z odpowiada za relacje = i <>

* Z=1 - A = B
* Z=0 - A <> B

Metoda nie modyfikuje znacznika C. Nadaje się do porównywania liczb BCD i U2.

== A ? B ==

Tradycyjna metoda porównywania liczb wielobajtowych

<pre>
lda dataA
cmp dataB
lda dataA+1
sbc dataB+1
...
lda dataA+N
sbc dataB+N
</pre>

pozwala na testowanie wyłącznie relacji < i >=:

* C=0 - A < B
* C=1 - A >= B

Porównując liczby od najstarszego bajtu można dokonać testu relacji <, =, >

<pre>
lda dataA+N
cmp dataB+N
bcc mniejsze
bne wieksze
lda dataA+N-1
cmp dataB+N-1
bcc mniejsze
bne wieksze
...
lda dataA
cmp dataB
bcc mniejsze
bne wieksze
rowne:
...
wieksze:
...
mniejsze:
...
</pre>

Działa dla BCD (nie wymaga wcześniejszego ustawienia bitu D).

Wykorzystując zmienną roboczą można testować relacje <. =, >=, >:

<pre>
sec
lda dataA
sbc dataB
sta temp
lda dataA+1
sbc dataB+1
ora temp
sta temp
...
lda dataA+N
sbc dataB+N
ora temp
</pre>

Znaczniki Z i C odpowiadają za relacje:

* C=0 - A < B,
* Z=1 - A = B,
* C=1 - A >= B,
* C=1 przy uprzednim wykluczeniu Z=1 - A > B.

Dodatkowo znacznik V odpowiada za przepełnienie przy porównywaniu liczb U2.
Ta metoda nadaje się do porównań liczb BCD (wymaga wcześniejszego ustawienia bitu D).

Zamieniając miejscami argumenty można testować relacje >, =, <=

<pre>
sec
lda dataB
sbc dataA
sta temp
lda dataB+1
sbc dataA+1
ora temp
sta temp
...
lda dataB+N
sbc dataA+N
ora temp
</pre>

gdzie analogicznie:

* C=0 - A > B,
* Z=1 - A = B,
* C=1 - A <= B,
* C=1 przy uprzednim wykluczeniu Z=1 - A < B.

Znacznik V odpowiada za przepełnienie przy porównywaniu liczb U2.
Ta metoda również nadaje się do porównań liczb BCD (wymaga wcześniejszego ustawienia bitu D).

'''UWAGA'''
W dwóch ostatnich przypadkach znacznik N ulega zniszczeniu przy ostatnim ORA TEMP, więc w przypadku porównywania liczb U2 można test na N wykonać wcześniej.

[[Kategoria:Niezbędnik kodera]]

Porównywanie liczb wielobajtowych - Historia wersji

imported>Atariki recovery: Reconstructed from archived HTML; see provenance manifest