imported>Atariki recovery: Reconstructed from archived HTML; see provenance manifest

2026-10-01T08:51:48Z

Reconstructed from archived HTML; see provenance manifest

Nowa strona

Procedura czeka, aż użytkownik naciśnie jakiś klawisz na klawiaturze, po czym zwraca odpowiedni kod w akumulatorze.

== GET zwracające [[Kody klawiszy|kod klawiatury]] ==

<code>
</code>

<pre>kbcodes = $02fc
;
getkbc lda kbcodes
cmp #$ff
beq getkbc
ldx #$ff
stx kbcodes
rts
</pre>

Zaletą użycia <code>KBCODES</code> jest łatwość monitorowania stanu tej zmiennej bez konieczności czekania na naciśnięcie klawisza przez użytkownika (patrz niżej). Kod ATASCII można tu uzyskać przez kombinację obu sposobów, tzn. wywołanie <code>getkey</code> wtedy, kiedy <code>KBCODES</code> zasygnalizuje naciśnięcie klawisza. Oszczędza to kłopotu z użyciem wektora tablicy definicji klawiatury, który w nowszych wersjach OS istnieje, a w starszych nie.

== GET zwracające kod [[ATASCII]] ==

Obie poniższe procedury wywołują tę samą funkcję OS. Jej - czasem niepożądaną - cechą jest to, że wstrzymuje wykonywanie programu aż do naciśnięcia klawisza przez użytkownika.

=== Wersja elegancka, ale długa ===

<code>
</code>

<pre>kname .byte "K:",$9B
;
cioexe sta iccmd,x
jmp jciomain
;
getkey jsr lookup
bmi error
;
lda #<kname
sta icbufa,x
lda #>kname
sta icbufa+1,x
lda #$04
sta icax1,x
lda #$00
sta icax2,x
lda #$03
jsr cioexe
bmi error ;w dobrze zdebugowanym programie raczej nie wystąpi tu błąd
;
lda #$00
sta icbufl,x
sta icbufl+1,x
lda #$07
jsr cioexe
bmi error ;np. naciśnięto Break
;
pha
lda #$0c
jsr cioexe
pla
rts
;
error ...
</pre>

Procedura '''lookup''' jest do znalezienia [[Programowanie: Jak wyszukać pierwszy wolny IOCB|tutaj]]. Reszta to etykiety systemowe.

Zaletą takiego sposobu odczytywania danych z klawiatury jest zgodność z każdym rodzajem klawiatury, byleby tylko był zainstalowany w systemie właściwy dlań sterownik "K:".

=== Wersja krótka, ale nieelegancka ===

<code>
</code>

<pre>getkey lda $e425
pha
lda $e424
pha
rts
</pre>

Zaletą tego sposobu jest to, że procedura zajmuje tylko 9 bajtów; powinna też zawsze działać, gdyż korzysta z umieszczonego w ROM-ie wektora wskazującego procedurę odczytu bajtu z klawiatury, z którego to wektora korzysta też [[CIO]]. Niemniej jest to "półlegalna" metoda wywoływania systemu operacyjnego: te wektory nie są przeznaczone dla programów użytkownika, a to, że w każdej wersji OS-u są w tym samym miejscu wynika po prostu z faktu, że nie ma szczególnego powodu przenosić ich gdzie indziej.

Wadą tej metody jest to, że omija ona tablicę urządzeń HATABS - a więc ewentualny handler zainstalowany przez użytkownika nie zostanie wywołany.

=== Wersja najkrótsza, zależna od SO, do ograniczonego zastosowania ===

<code>
</code>

<pre> jsr $f2fd
</pre>

Funkcja ta zwraca kod ATASCII w akumulatorze. Zastosowanie tej funkcji ogranicza się do szybkich programików, wprawek, tam, gdzie liczy się ilość kodu.
Funkcja ta czeka na znak. Jeśli nie chcemy, aby funkcja nie czekała na znak, tylko zwracała go wyłącznie jeśli został naciśnięty, to musimy skorzystać z rejestru CH (764, $2fc)

<code>
</code>

<pre> lda CH
cmp #255
beq skip
jsr $f2fd
skip
</pre>

Może być stosowana w parze z

<code>
</code>

<pre> jsr $f2b0
</pre>

która służy do wypisania znaku z akumulatora na ekran.

A oto najkrótszy edytor ekranowy (MEMO PAD)

<code>
</code>

<pre> org $2800
start
jsr $f2fd
jsr $f2b0
jmp start
</pre>

Metoda ta jest hackerska, używanie jej w dzisiejszych progamach to proszenie się o kłopoty (głównie u innych użytkowników).

[[Kategoria:Niezbędnik kodera]]

Odczyt znaku z klawiatury (GET) - Historia wersji

imported>Atariki recovery: Reconstructed from archived HTML; see provenance manifest