Tekst źródłowy strony Inkrementacja i dekrementacja liczb wielobajtowych

== Inkrementacja ==

Sekwencja rozkazów zwiększająca wartość dwubajtowej liczby całkowitej o 1 jest powszechnie znana i często używana:

<pre>
       inc zmienna
       bne koniec
       inc zmienna+1
koniec
</pre>

Sekwencja inkrementująca liczbę trzybajtową wygląda analogicznie:

<pre>
       inc zmienna
       bne koniec
       inc zmienna+1
       bne koniec
       inc zmienna+2
koniec
</pre>

Niektóre asemblery (np. [[MADS]]) oferują tu ułatwiające życie pseudorozkazy, odpowiednio INW oraz INL.

W przypadku liczb trzy- i więcej-bajtowych krótszy kod można uzyskać stosując pętlę (n - wielkość ''zmiennej'' w bajtach):

<pre>
       ldx #-n
petla  inc zmienna-$0100+n,x
       bne koniec
       inx
       bne petla
koniec
</pre>

Jeśli zaś chodzi o przeniesienie inkrementowanej wartości do innej zmiennej, pętla może wyglądać tak:

<pre>
       ldx #-n
       sec
petla  lda zmienna_a-$0100+n,x
       adc #$00
       sta zmienna_b-$0100+n,x
       inx
       bne petla
</pre>

Wykorzystano tu fakt, że rozkaz ADC dodaje do akumulatora wartość podanego argumentu plus wartość znacznika C.

Pętle nie zadziałają prawidłowo, jeśli ''zmienna'' znajduje się na stronie zerowej, do tego trzeba je odpowiednio zmodyfikować. Patrz [[Ujemne indeksowanie]].

== Dekrementacja ==

Dekrementacja dwubajtowej liczby całkowitej jest nieco bardziej kłopotliwa, niż inkrementacja takowej:

<pre>
       lda zmienna
       bne d1
       dec zmienna+1
d1     dec zmienna
</pre>

Przy liczbach trzy- i więcej-bajtowych krótszy kod uzyskamy stosując pętlę podobną do tej powyżej, wykorzystując fakt, że działanie znacznika C dla rozkazu SBC jest odwrotne niż dla ADC (SBC odejmuje od akumulatora podaną wartość zwiększoną o odwrotność znacznika C):

<pre>
       ldx #-n
       clc
petla  lda zmienna-$0100+n,x
       sbc #$00
       sta zmienna-$0100+n,x
       inx
       bne petla
</pre>

'n' to, jak powyżej, wielkość ''zmiennej'' w bajtach. Dla liczby trzybajtowej zysk wynosi 5 bajtów, a dla czterobajtowej - aż 13. Jak powyżej, jeśli ''zmienna'' jest na stronie zerowej, pętlę trzeba odpowiednio zmodyfikować.

[[Kategoria:Niezbędnik kodera]]